Abstract
Revenue Sharing is an extended version of the standard token. It proposes an additional payment method for token holders.
This standard includes updating rewards for holders and allowing token holders to withdraw rewards.
Specification
IERC7254
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
/**
* @dev Interface of the ERC7254 standard as defined in the EIP.
*/
interface IERC7254 {
struct UserInformation {
uint256 inReward;
uint256 outReward;
uint256 withdraw;
}
/**
* @dev Emitted when `value` tokens are moved from one account (`from`) to
* another (`to`).
*
* Note that `value` may be zero.
*/
event Transfer(address indexed from, address indexed to, uint256 value);
/**
* @dev Emitted when the allowance of a `spender` for an `owner` is set by
* a call to {approve}. `value` is the new allowance.
*/
event Approval(address indexed owner, address indexed spender, uint256 value);
/**
* @dev Emitted when the add reward of a `contributor` is set by
* a call to {approve}.
*/
event UpdateReward(address indexed contributor, uint256 value);
/**
* @dev Emitted when `value` tokens reward to
* `caller`.
*
* Note that `value` may be zero.
*/
event GetReward(address indexed owner, uint256 value);
/**
* @dev Returns the amount of tokens in existence.
*/
function totalSupply() external view returns (uint256);
/**
* @dev Returns the amount of tokens owned by `account`.
*/
function balanceOf(address account) external view returns (uint256);
/**
* @dev Returns user information by `account`.
*/
function informationOf(address account) external view returns (UserInformation memory);
/**
* @dev Returns token reward.
*/
function tokenReward() external view returns (address);
/**
* @dev Moves `amount` tokens from the caller's account to `to`.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* Emits a {Transfer} event.
*/
function transfer(address to, uint256 amount) external returns (bool);
/**
* @dev Returns the remaining number of tokens that `spender` will be
* allowed to spend on behalf of `owner` through {transferFrom}. This is
* zero by default.
*
* This value changes when {approve} or {transferFrom} are called.
*/
function allowance(address owner, address spender) external view returns (uint256);
/**
* @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* Emits an {Approval} event.
*/
function approve(address spender, uint256 amount) external returns (bool);
/**
* @dev Moves `amount` tokens from `from` to `to` using the
* allowance mechanism. `amount` is then deducted from the caller's
* allowance.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* Emits a {Transfer} event.
*/
function transferFrom(
address from,
address to,
uint256 amount
) external returns (bool);
/**
* @dev Add `amount` tokens .
*
* Returns a rewardPerShare.
*
* Emits a {UpdateReward} event.
*/
function updateReward(uint256 amount) external returns(uint256);
/**
* @dev Returns the amount of reward by `account`.
*/
function viewReward(address account) external returns (uint256);
/**
* @dev Moves reward to caller.
*
* Returns a amount value of reward.
*
* Emits a {GetReward} event.
*/
function getReward() external returns(uint256);
}
IERC7254Metadata
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;
import "./IERC7254.sol";
/**
* @dev Interface for the optional metadata functions from the ERC7254 standard.
*
* _Available since v4.1._
*/
interface IERC7254Metadata is IERC7254 {
/**
* @dev Returns the name of the token.
*/
function name() external view returns (string memory);
/**
* @dev Returns the symbol of the token.
*/
function symbol() external view returns (string memory);
/**
* @dev Returns the decimals places of the token.
*/
function decimals() external view returns (uint8);
}
ERC7254
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.9;
import "@openzeppelin/contracts/utils/Context.sol";
import "./IERC7254Metadata.sol";
import "./IERC7254.sol";
/**
* @dev Implementation of the {IERC7254} interface.
*
* This implementation is agnostic to the way tokens are created. This means
* that a supply mechanism has to be added in a derived contract using {_mint}.
* Additionally, an {Approval} event is emitted on calls to {transferFrom}.
* This allows applications to reconstruct the allowance for all accounts just
* by listening to said events. Other implementations of the EIP may not emit
* these events, as it isn't required by the specification.
*
* Finally, the non-standard {decreaseAllowance} and {increaseAllowance}
* functions have been added to mitigate the well-known issues around setting
* allowances. See {IERC7254-approve}.
*/
contract ERC7254 is Context, IERC7254, IERC7254Metadata {
mapping(address => UserInformation) private userInformation;
mapping(address => uint256) private _balances;
mapping(address => mapping(address => uint256)) private _allowances;
uint256 private _totalSupply;
string private _name;
string private _symbol;
uint256 public rewardPerShare;
address private _tokenReward;
/**
* @dev Sets the values for {name} and {symbol} and {tokenReward}.
*
* The default value of {decimals} is 18. To select a different value for
* {decimals} you should overload it.
*
* All three of these values are immutable: they can only be set once during
* construction.
*/
constructor(string memory name_, string memory symbol_, address tokenReward_) {
_name = name_;
_symbol = symbol_;
_tokenReward = tokenReward_;
}
/**
* @dev Returns the name of the token.
*/
function name() public view virtual override returns (string memory) {
return _name;
}
/**
* @dev Returns the symbol of the token, usually a shorter version of the
* name.
*/
function symbol() public view virtual override returns (string memory) {
return _symbol;
}
/**
* @dev Returns the number of decimals used to get its user representation.
* For example, if `decimals` equals `2`, a balance of `505` tokens should
* be displayed to a user as `5.05` (`505 / 10 ** 2`).
*
* Tokens usually opt for a value of 18, imitating the relationship between
* Ether and Wei. This is the value {ERC7254} uses, unless this function is
* overridden;
*
* NOTE: This information is only used for _display_ purposes: it in
* no way affects any of the arithmetic of the contract, including
* {IERC7254-balanceOf} and {IERC7254-transfer}.
*/
function decimals() public view virtual override returns (uint8) {
return 18;
}
/**
* @dev See {IERC7254-totalSupply}.
*/
function totalSupply() public view virtual override returns (uint256) {
return _totalSupply;
}
/**
* @dev See {IERC7254-balanceOf}.
*/
function balanceOf(address account) public view virtual override returns (uint256) {
return _balances[account];
}
/**
* @dev Returns user information by `account`.
*/
function informationOf(address account) public view virtual override returns (UserInformation memory) {
return userInformation[account];
}
/**
* @dev See {IERC7254-transfer}.
*
* Requirements:
*
* - `to` cannot be the zero address.
* - the caller must have a balance of at least `amount`.
*/
function transfer(address to, uint256 amount) public virtual override returns (bool) {
address owner = _msgSender();
_transfer(owner, to, amount);
return true;
}
/**
* @dev See {IERC7254-allowance}.
*/
function allowance(address owner, address spender) public view virtual override returns (uint256) {
return _allowances[owner][spender];
}
/**
* @dev See {IERC7254-approve}.
*
* NOTE: If `amount` is the maximum `uint256`, the allowance is not updated on
* `transferFrom`. This is semantically equivalent to an infinite approval.
*
* Requirements:
*
* - `spender` cannot be the zero address.
*/
function approve(address spender, uint256 amount) public virtual override returns (bool) {
address owner = _msgSender();
_approve(owner, spender, amount);
return true;
}
/**
* @dev See {IERC7254-transferFrom}.
*
* Emits an {Approval} event indicating the updated allowance. This is not
* required by the EIP. See the note at the beginning of {ERC7254}.
*
* NOTE: Does not update the allowance if the current allowance
* is the maximum `uint256`.
*
* Requirements:
*
* - `from` and `to` cannot be the zero address.
* - `from` must have a balance of at least `amount`.
* - the caller must have allowance for ``from``'s tokens of at least
* `amount`.
*/
function transferFrom(
address from,
address to,
uint256 amount
) public virtual override returns (bool) {
address spender = _msgSender();
_spendAllowance(from, spender, amount);
_transfer(from, to, amount);
return true;
}
/**
* @dev Atomically increases the allowance granted to `spender` by the caller.
*
* This is an alternative to {approve} that can be used as a mitigation for
* problems described in {IERC7254-approve}.
*
* Emits an {Approval} event indicating the updated allowance.
*
* Requirements:
*
* - `spender` cannot be the zero address.
*/
function increaseAllowance(address spender, uint256 addedValue) public virtual returns (bool) {
address owner = _msgSender();
_approve(owner, spender, allowance(owner, spender) + addedValue);
return true;
}
/**
* @dev Atomically decreases the allowance granted to `spender` by the caller.
*
* This is an alternative to {approve} that can be used as a mitigation for
* problems described in {IERC7254-approve}.
*
* Emits an {Approval} event indicating the updated allowance.
*
* Requirements:
*
* - `spender` cannot be the zero address.
* - `spender` must have allowance for the caller of at least
* `subtractedValue`.
*/
function decreaseAllowance(address spender, uint256 subtractedValue) public virtual returns (bool) {
address owner = _msgSender();
uint256 currentAllowance = allowance(owner, spender);
require(currentAllowance >= subtractedValue, "ERC7254: decreased allowance below zero");
unchecked {
_approve(owner, spender, currentAllowance - subtractedValue);
}
return true;
}
/**
* @dev Moves `amount` of tokens from `from` to `to`.
* Add inReward of `from` and add outReward of `to` with amount.
* This internal function is equivalent to {transfer}, and can be used to
* e.g. implement automatic token fees, slashing mechanisms, etc.
*
* Emits a {Transfer} event.
*
* Requirements:
*
* - `from` cannot be the zero address.
* - `to` cannot be the zero address.
* - `from` must have a balance of at least `amount`.
*/
function _transfer(
address from,
address to,
uint256 amount
) internal virtual {
require(from != address(0), "ERC7254: transfer from the zero address");
require(to != address(0), "ERC7254: transfer to the zero address");
_beforeTokenTransfer(from, to, amount);
uint256 fromBalance = _balances[from];
require(fromBalance >= amount, "ERC7254: transfer amount exceeds balance");
unchecked {
_balances[from] = fromBalance - amount;
// Overflow not possible: the sum of all balances is capped by totalSupply, and the sum is preserved by
// decrementing then incrementing.
_balances[to] += amount;
}
UserInformation storage userSender = userInformation[from];
userSender.inReward += amount * rewardPerShare;
UserInformation storage userTo = userInformation[to];
userTo.outReward += amount * rewardPerShare;
emit Transfer(from, to, amount);
_afterTokenTransfer(from, to, amount);
}
/** @dev Creates `amount` tokens and assigns them to `account`, increasing
* the total supply.
* Add outReward of `account` with amount.
* Emits a {Transfer} event with `from` set to the zero address.
*
* Requirements:
*
* - `account` cannot be the zero address.
*/
function _mint(address account, uint256 amount) internal virtual {
require(account != address(0), "ERC7254: mint to the zero address");
_beforeTokenTransfer(address(0), account, amount);
_totalSupply += amount;
unchecked {
// Overflow not possible: balance + amount is at most totalSupply + amount, which is checked above.
_balances[account] += amount;
}
UserInformation storage userMint = userInformation[account];
userMint.outReward += amount * rewardPerShare;
emit Transfer(address(0), account, amount);
_afterTokenTransfer(address(0), account, amount);
}
/**
* @dev Destroys `amount` tokens from `account`, reducing the
* total supply.
* Add inReward of `account` with amount.
* Emits a {Transfer} event with `to` set to the zero address.
*
* Requirements:
*
* - `account` cannot be the zero address.
* - `account` must have at least `amount` tokens.
*/
function _burn(address account, uint256 amount) internal virtual {
require(account != address(0), "ERC7254: burn from the zero address");
_beforeTokenTransfer(account, address(0), amount);
uint256 accountBalance = _balances[account];
require(accountBalance >= amount, "ERC7254: burn amount exceeds balance");
unchecked {
_balances[account] = accountBalance - amount;
// Overflow not possible: amount <= accountBalance <= totalSupply.
_totalSupply -= amount;
}
UserInformation storage userBurn = userInformation[account];
userBurn.inReward += amount * rewardPerShare;
emit Transfer(account, address(0), amount);
_afterTokenTransfer(account, address(0), amount);
}
/**
* @dev Sets `amount` as the allowance of `spender` over the `owner` s tokens.
*
* This internal function is equivalent to `approve`, and can be used to
* e.g. set automatic allowances for certain subsystems, etc.
*
* Emits an {Approval} event.
*
* Requirements:
*
* - `owner` cannot be the zero address.
* - `spender` cannot be the zero address.
*/
function _approve(
address owner,
address spender,
uint256 amount
) internal virtual {
require(owner != address(0), "ERC7254: approve from the zero address");
require(spender != address(0), "ERC7254: approve to the zero address");
_allowances[owner][spender] = amount;
emit Approval(owner, spender, amount);
}
/**
* @dev Updates `owner` s allowance for `spender` based on spent `amount`.
*
* Does not update the allowance amount in case of infinite allowance.
* Revert if not enough allowance is available.
*
* Might emit an {Approval} event.
*/
function _spendAllowance(
address owner,
address spender,
uint256 amount
) internal virtual {
uint256 currentAllowance = allowance(owner, spender);
if (currentAllowance != type(uint256).max) {
require(currentAllowance >= amount, "ERC7254: insufficient allowance");
unchecked {
_approve(owner, spender, currentAllowance - amount);
}
}
}
/**
* @dev Hook that is called before any transfer of tokens. This includes
* minting and burning.
*
* Calling conditions:
*
* - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
* will be transferred to `to`.
* - when `from` is zero, `amount` tokens will be minted for `to`.
* - when `to` is zero, `amount` of ``from``'s tokens will be burned.
* - `from` and `to` are never both zero.
*
* To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
*/
function _beforeTokenTransfer(
address from,
address to,
uint256 amount
) internal virtual {}
/**
* @dev Hook that is called after any transfer of tokens. This includes
* minting and burning.
*
* Calling conditions:
*
* - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
* has been transferred to `to`.
* - when `from` is zero, `amount` tokens have been minted for `to`.
* - when `to` is zero, `amount` of ``from``'s tokens have been burned.
* - `from` and `to` are never both zero.
*
* To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
*/
function _afterTokenTransfer(
address from,
address to,
uint256 amount
) internal virtual {}
/**
* @dev Returns token reward.
*/
function tokenReward() public view virtual override returns (address) {
return _tokenReward;
}
/**
* @dev Add `amount` tokens .
*
* Returns a rewardPerShare.
*
* Emits a {UpdateReward} event.
*/
function updateReward(uint256 amount) public virtual override returns(uint256) {
address owner = _msgSender();
if(totalSupply() != 0){
IERC7254(_tokenReward).transferFrom(owner, address(this), amount);
rewardPerShare = rewardPerShare + amount * 1e18/ totalSupply();
}
emit UpdateReward(owner, amount);
return rewardPerShare;
}
/**
* @dev Returns the amount of reward by `account`.
*/
function viewReward(address account) public view virtual override returns (uint256){
UserInformation storage user = userInformation[account];
uint256 reward = _balances[account] * rewardPerShare + user.inReward - user.withdraw - user.outReward;
return reward / 1e18;
}
/**
* @dev Moves reward to caller.
*
* Returns a amount value of reward.
*
* Emits a {GetReward} event.
*/
function getReward() public virtual override returns(uint256){
address owner = _msgSender();
UserInformation storage user = userInformation[owner];
uint256 reward = _balances[owner] * rewardPerShare + user.inReward - user.withdraw - user.outReward;
_withdraw(owner, reward);
if(reward / 1e18 > 0){
IERC7254(_tokenReward).transfer(owner, reward / 1e18);
}
emit GetReward(owner, reward);
return reward;
}
/**
* @dev add reward withdraw of owner.
*
*/
function _withdraw(address owner, uint256 reward) internal virtual {
require(owner != address(0), "ERC7254: withdraw from the zero address");
UserInformation storage user = userInformation[owner];
user.withdraw += reward;
}
}
Methods
name
Returns the name of the token
function name() public view returns (string)
symbol
Returns the symbol of the token
function symbol() public view returns (string)
decimals
Returns the number of decimals the token uses.
function decimals() public view returns (uint8)
totalSupply
Returns the total token supply.
function totalSupply() public view returns (uint256)
balanceOf
Returns the account balance of another account with address “account”.
function balanceOf(address account) public view returns (uint256)
informationOf
Returns the account information of another account with the address “account”, including: inReward, outReward and withdraw.
function informationOf(address account) public view returns (UserInformation memory)
transfer
Transfer amount of tokens to the address “to”.
function transfer(address to, uint256 amount) public returns (bool)
allowance
Returns the amount which the spender is still allowed to withdraw from the owner.
function allowance(address owner, address spender) public view returns (uint256)
approve
Allows the spender to withdraw from your account multiple times, up to the specified amount.
function approve(address spender, uint256 amount) public returns (bool)
transferFrom
Transfer amount of tokens from address “from” to the address “to”
function transferFrom(address from, address to, uint256 amount) public returns (bool)
tokenReward
Returns the token reward address of the token.
function tokenReward() public view returns (address)
updateReward
Updates rewardPerShare and returns rewardPerShare
function updateReward(uint256 amount) public returns(uint256)
viewReward
Returns the amount of reward for an account
function viewReward(address account) public view returns (uint256)
getReward
Gets and returns reward
function getReward() public virtual override returns(uint256)